このページは機械翻訳を使用して翻訳されました。最新版の英語を参照するには、ここをクリックします。

セキュアなMQTTパブリッシュとサブスクライブを使用したリモートセンサー制御

この例では、ThingSpeak で MQTT パブリッシュおよびサブスクライブアーキテクチャを使用する方法を示します。MQTT プロトコルは、オーバーヘッドの少ないデバイスメッセージングシステムです。MQTT を使用して、制御チャネルのフィールド 1 をサブスクライブします。制御チャネルを更新すると、投稿された値がデバイスに送信されます。サーボは指定された角度まで回転します。デバイスはネットワークの強度を測定し、ストレージチャネルを更新します。コード内のコメントは、この例を安全でない接続に適合させる方法を示しています。

サポート対象のハードウェア

ESP8266、NodeMCU、WeMOS
アルドゥイーノMKR1000
ワイヤレスネットワーク接続を備えた Arduino Uno、Mega、Due、または Leonardo
Particle Photon （コードと回路図を若干調整）

この例は、いくつかの追加コンポーネント、つまり単一のサーボモーターのみで動作するように設計されています。オンボード Wi-Fi アンテナを使用して、Wi-Fi 強度を測定します。

これらの画像は、ストレージチャネルからのサンプルチャネル出力を示しています。フィールド 1 には制御チャネルから設定されたサーボモーターの角度が格納され、フィールド 2 には測定された Wi-Fi 強度の値が表示されます。

データ解析により、WeMOS ハードウェアの向きが測定された信号強度に方向性の影響を及ぼすことが示されました。

前提条件

1) 新しいチャネルでデータを収集するに示すように、サブスクライブコントロール用の ThingSpeakチャネルを作成します。サブスクライブチャネルは、サーボモーターの角度を保持します。サーボモーターの角度が更新されると、サブスクライブされたデバイスは角度を MQTT メッセージとして受信します。デバイスはサーボの角度を設定し、その角度で新しいワイヤレスネットワークの強度を測定します。

2) 公開されたデータ用に別の ThingSpeakチャネルを作成します。公開チャネルは、設定された角度と信号強度データを記録します。

3) 「チャネル設定 」ビューで、公開チャネルのフィールド 1 と 2 を有効にします。フィールドを区別するには、各フィールドにわかりやすい名前を付けます。

4) 「チャネル設定」 ビューの 「API キー」 タブにある読み取り API キーと書き込み API キーをメモします (画像で丸で囲まれている部分)。

5) ページ上部の [Devices] > [MQTT] をクリックし、[Add a new device] をクリックして、MQTT デバイスを作成します。デバイスをセットアップするときに、公開とサブスクライブの両方のチャネルを承認します。詳細は、ThingSpeak MQTTデバイスを作成するを参照してください。

6) 新しいデバイスを追加する際に、[Download Credentials] > [Arduino (mqtt_secrets.h)] をクリックします。以下のコードセクションでアクセスできるように、ダウンロードしたシークレットファイルを保存しておきます。

必要なハードウェア

WeMOS D1 Mini、または使用するライブラリに変更を加えた以下のいずれかのデバイス:NodeMCU、ESP8266-01、ESP8266-04、ESP8266-12、ESP8266-12E、Arduino® MKR1000、またはイーサネットまたはワイヤレスネットワーク接続を備えたその他のArduino
サーボモーター（例：Futaba S3003）
ジャンパー線（少なくとも3本）
USBケーブル

回路図と接続

1) WeMOS D1 MiniのD5をサーボの信号線に接続します。

2) サーボのアース線を WeMOS ボードのアースに接続します。

3) サーボ電源を 3.3 V に接続します。5 V を直接使用すると、場合によっては USB 電源制限を超える可能性があります。

Arduino をプログラムする

Arduino IDE を使用してデバイスをプログラムします。最新の Arduino IDE はこちらからダウンロードできます。

1) ESP8266 ボードパッケージを追加します。

a.File > Preferences で、Additional Board Manager URLs に「https://arduino.esp8266.com/stable/package_esp8266com_index.json」と入力します。

b.[Tools] > [Boards] > [Board Manager] を選択します。検索バーに「ESP8266」と入力してパッケージをインストールします。

2) 許可されるパケットサイズを変更します。

a.pub sub ライブラリヘッダーファイル (通常は Documents\Arduino\libraries\PubSubClient\src) があるフォルダーに移動します。

b.PubSubClient.h to c を編集して、最大パケットサイズを 4096 に変更します。完了すると、行は次のようになります。

#define MQTT_MAX_PACKET_SIZE 4096

3) アプリケーションを作成します。

a.Arduino IDE で新しいウィンドウを開き、ファイルを保存します。

b.コードセクションで提供されているコードを追加します。

c.コード内のワイヤレスネットワーク情報とチャネルID を必ず編集してください。

4) スケッチにライブラリとシークレットファイルを追加します。

a.まだ存在しない場合は、[Sketch] > [Include Library] > [Manage Libraries] を選択して、次のライブラリをライブラリマネージャーに追加します。各ライブラリの名前を検索し、インストール を選択します。

PubSubClient
ESP8266Wifi
servo

b.mqtt_secrets.h ファイルを追加します。

デバイスをテスト

プログラムを正常にアップロードしたら、シリアルモニターを使用して出力を監視できます。0 ～ 175 の範囲の値を ThingSpeak コントロールチャネルにアップロードします。API キー タブからGET要求形式をコピーするか、書き込み API キーを使用してこのテキストを変更できます。各 URL をブラウザのアドレスバーに直接入力し、YOUR WRITE API KEY を自分のチャネルの書き込み API キーに変更します。

https://api.thingspeak.com/update?api_key=YOUR_WRITE_API_KEY&field1=ANGLE_VALUE

デバイスは、サブスクライブチャネルに投稿するたびに、角度と Wi-Fi 信号強度をストレージチャネルに公開します。角度の値が 0 ～ 175 の範囲内であることを確認してください。

コード

1) 必要なライブラリをインクルードし、データフィールドを定義します。

#include <PubSubClient.h>
#include <WiFiClientSecure.h>                         // Needed only if using secure connection.
#include <ESP8266WiFi.h>
#include <Servo.h> 
#include "mqtt_secrets.h"
#define ANGLE_FIELD 0   
#define DATA_FIELD 1                                  // Data field to post the signal strength to.

2) 変数を定義して初期化します。ワイヤレスネットワーク情報、チャネルID、資格情報を必ず編集してください。チャネルのメインページの上部でチャネルID を見つけます。

char ssid[] = "YOUR_SSID";                   // Change to your network SSID (name).
char pass[] = "YOUR_WIFI_PASSWORD";          // Change to your network password.
const char* server = "mqtt3.thingspeak.com";
char mqttUserName[] = SECRET_MQTT_USERNAME;  // Change to your MQTT device username.    
char mqttPass[] = SECRET_MQTT_PASSWORD;      // Change to your MQTT device password.
char clientID[] = SECRET_MQTT_CLIENT_ID;     // Change to your MQTT device clientID.
long readChannelID = 85;
long writeChannelID = 86;

// Here's how to get ThingSpeak server fingerprint: https://www.a2hosting.com/kb/security/ssl/a2-hostings-ssl-certificate-fingerprints
const char* thingspeak_server_fingerprint = "27 18 92 dd a4 26 c3 07 09 b9 7a e6 c5 21 b9 5b 48 f7 16 e1";

// WiFiClient client;                                 // Initialize the Wi-Fi client library. Uncomment for nonsecure connection.
WiFiClientSecure client;                              // Uncomment for secure connection.  
PubSubClient mqttClient( client );                    // Initialize the PuBSubClient library.
Servo myservo;  // Create servo object to control a servo .

int fieldsToPublish[8]={1,1,0,0,0,0,0,0};             // Change to allow multiple fields.
float dataToPublish[8];                               // Holds your field data.
int changeFlag=0;                                     // Let the main loop know there is new data to set.
int servo_pos=0;                                      // Servo position

3) このコードで関数のプロトタイプを定義します。

//  
// Prototypes
//

// Handle messages from MQTT subscription.
void mqttSubscriptionCallback(char* topic, byte* payload, unsigned int length);  

// Generate a unique client ID and connect to MQTT broker.
void mqttConnect();  

// Subscribe to a field or feed from a ThingSpeak channel.
int mqttSubscribe( long subChannelID,int field, int unSub);

// Publish messages to a channel feed.

// Connect to a given Wi-Fi SSID.
int connectWifi();

// Measure the Wi-Fi signal strength.
void updateRSSIValue();

4) setup ルーチンで、入力および出力のピンを初期化し、シリアルモニターを起動し、MQTT クライアントを初期化します。

void setup() {
Serial.begin( 115200 );
Serial.println( "Start" );
int status = WL_IDLE_STATUS; // Set temporary Wi-Fi status.
       
    connectWifi();                                        // Connect to Wi-Fi network.
    // mqttClient.setServer( server, 1883 );              // Set the MQTT broker details, nonsecure port. Uncomment for nonsecure connection.
    mqttClient.setServer( server, 8883 );                 // Set the MQTT broker details, secure port. Uncomment for secure connection.
    mqttClient.setCallback( mqttSubscriptionCallback );   // Set the MQTT message handler function.
    myservo.attach(14);                                   // Attach the servo on GIO2 to the servo object. 
    myservo.write(90);                                    // Start in the middle.
}

5) メインループが実行されるたびに、MQTT サブスクリプションからのデータが処理可能かどうかを確認します。次に、データに合わせてサーボの位置を設定します。ワイヤレスクライアントと MQTT クライアントがアクティブであり、クライアントサーバーへの接続が維持されていることを確認します。

void loop() {
    
    if (WiFi.status() != WL_CONNECTED) {
        connectWifi();
    }
    
    if (!mqttClient.connected())
    {
       
       mqttConnect(); // Connect if MQTT client is not connected.
        
         if(mqttSubscribe( readChannelID,1,0 )==1 ){
                Serial.println( " Subscribed " );
            }
    }
    
    mqttClient.loop(); // Call the loop to maintain connection to the server.                         

    if ((servo_pos>175)||(servo_pos<0)){
    servo_pos=0;
    }
   
    if (changeFlag){
      
        changeFlag=0;
        myservo.write(servo_pos);
        dataToPublish[ANGLE_FIELD]=servo_pos;
        delay(1100);                       // Wait for ThingSpeak to publish.
        Serial.println( "Servo value " + String( servo_pos ) );
        mqttPublish( writeChannelID, dataToPublish, fieldsToPublish );
    }
    
    delay(1);
}

6) mqttSubscriptionCallback 関数を使用して、受信した MQTT メッセージを処理します。メインループがコールバックの代わりに処理手順を実行すると、プログラムはよりスムーズに実行されます。この関数では、フラグを使用してメインループに変更を加えます。

/**
 * Process messages received from subscribed channel via MQTT broker.
 *   topic - Subscription topic for message.
 *   payload - Field to subscribe to. Value 0 means subscribe to all fields.
 *   mesLength - Message length.
 */

void mqttSubscriptionCallback( char* topic, byte* payload, unsigned int mesLength ) {
    
    char p[mesLength + 1];
    memcpy( p, payload, mesLength );
    p[mesLength] = NULL;
    Serial.print( "Answer: " );
    Serial.println( String(p) );
    servo_pos=atoi( p );
    changeFlag=1;
}

7) MQTTConnect 関数を使用して、MQTT への接続を設定および維持します。

void mqttConnect()
{
    // Loop until connected.
    while ( !mqttClient.connected() )
    {
      Serial.println(String( mqttUserName)+ " , " + mqttPass + " , " + clientID);
   
        // Connect to the MQTT broker.
        Serial.print( "Attempting MQTT connection..." );
        if ( mqttClient.connect( clientID, mqttUserName, mqttPass ) )
        {
            Serial.println( "Connected with Client ID:  " + String( clientID ) + " User "+ String( mqttUserName ) + " Pwd "+String( mqttPass ) );
           
        } else
        {
            Serial.print( "failed, rc = " );
            // See https://pubsubclient.knolleary.net/api.html#state for the failure code explanation.
            Serial.print( mqttClient.state() );
            Serial.println( " Will try again in 5 seconds" );
            delay( 5000 );
        }
    }
}

8) mqttSubscribe を使用して、LED 制御フィールドから更新を受信します。この例では、フィールドをサブスクライブしていますが、この関数を使用してチャネルフィード全体をサブスクライブすることもできます。フィード全体をサブスクライブするには、field = 0 を使用して関数を呼び出します。

/**
 * Subscribe to fields of a channel.
 *   subChannelID - Channel to subscribe to.
 *   field - Field to subscribe to. Value 0 means subscribe to all fields.
 *   readKey - Read API key for the subscribe channel.
 *   unSub - Set to 1 for unsubscribe.
 */
 
int mqttSubscribe( long subChannelID, int field, int unsubSub ){
    String myTopic;
    
    // There is no field zero, so if field 0 is sent to subscribe to, then subscribe to the whole channel feed.
    if (field==0){
        myTopic="channels/"+String( subChannelID )+"/subscribe";
    }
    else{
        myTopic="channels/"+String( subChannelID )+"/subscribe/fields/field"+String( field );
    }
    
    Serial.println( "Subscribing to " +myTopic );
    Serial.println( "State= " + String( mqttClient.state() ) );

    if ( unsubSub==1 ){
        return mqttClient.unsubscribe(myTopic.c_str());
    }
    return mqttClient.subscribe( myTopic.c_str() ,0 );
}

9) mqttUnsubscribe 関数はコードでは使用されていませんが、サブスクリプションを終了するために使用できます。

/**
 * Unsubscribe channel
 *   subChannelID - Channel to unsubscribe from.
 *   field - Field to unsubscribe subscribe from. The value 0 means subscribe to all fields.
 *   readKey - Read API key for the subscribe channel.
 */

int mqttUnSubscribe(long subChannelID,int field,char* readKey){
    String myTopic;
    
    if (field==0){
         myTopic="channels/"+String( subChannelID )+"/subscribe";
    }
    else{
        myTopic="channels/"+String( subChannelID )+"/subscribe/fields/field"+String( field );
    }
    return mqttClient.unsubscribe( myTopic.c_str() );   
}

10) mqttPublish 関数を使用して、角度と Wi-Fi RSSI データを ThingSpeakチャネルに送信します。

/**
 * Publish to a channel
 *   pubChannelID - Channel to publish to.
 *   pubWriteAPIKey - Write API key for the channel to publish to.
 *   dataArray - Binary array indicating which fields to publish to, starting with field 1.
 *   fieldArray - Array of values to publish, starting with field 1.
 */

void mqttPublish(long pubChannelID, float dataArray[], int fieldArray[]) {
    int index=0;
    String dataString="";
    
    updateRSSIValue();  // Make sure the stored value is updated.
    
    // 
    while (index<8){
        
        // Look at the field array to build the posting string to send to ThingSpeak.
        if (fieldArray[ index ]>0){
          
            dataString+="&field" + String( index+1 ) + "="+String( dataArray [ index ] );
        }
        index++;
    }
    
    Serial.println( dataString );
    
    // Create a topic string and publish data to ThingSpeak channel feed.
     String topicString ="channels/" + String( pubChannelID ) + "/publish";
    mqttClient.publish( topicString.c_str(), dataString.c_str() );
    Serial.println( "Published to channel " + String( pubChannelID ) );
}

11) connectWiFi 機能を使用してデバイスをワイヤレスネットワークに接続します。

int connectWifi()
{
    while ( WiFi.status() != WL_CONNECTED ) {
        WiFi.begin( ssid, pass );
        delay( 8500 );
        Serial.println( "Connecting to Wi-Fi" ); 
    }
    Serial.println( "Connected" );
    client.setFingerprint(thingspeak_server_fingerprint);  // Comment this line if using nonsecure connection.
}

12) updateRSSIValue 関数を使用して、現在接続しているネットワークの信号強度を読み取ります。

void updateRSSIValue(){

   long rssi = WiFi.RSSI();  
   Serial.print( "RSSI:" );
   Serial.println(rssi);
   dataToPublish[ DATA_FIELD ]=float( rssi );

}

参考

Write Data | MQTT Publish